### Polyphase AC Supply

About the writer: Harvey Morehouse is a contractor/consultant with many years of experience using circuit analysis programs. His primary activities are in Reliability, Safety, Testability and Circuit Analysis. He may be reached at harvey.annie@verizon.net. Simple questions for which I know the answer are free. Complex questions, especially where I am ignorant of the answers, are costly!!!

Summary: Polyphase AC supplies can easily be modeled using contributions from a sine and cosine wave signals to create appropriate phase shifted signals.

Creating a phase shifted signal:

Unfortunately the SPICE AC signal generator devices do not accommodate a phase shift input, rather they use a delay time for the waveform start. The problem is that for a fixed phase shift, as the frequency varies, the delay representing this phase shift will also change.

For some reason this represents quite a challenge to users, as opposed to creating a simple device or devices that will direct accommodate not only a phase shift input signal but a varying phase shift represented by a waveform, that will be invarient with frequency. The steps in creating such a device follow.

Figure 1 shows a representation of an ac sinusoidal signal as a phasor. Figure 1
Phasor representation of an AC waveform

The AC waveform is shown to the right as a 'rough' sine wave. The phasor representation is shown as a line from the origin, of unit length, rotating counter-clockwise about the origin. Its 'shadow' or projection on the 'Y' axis, as it rotates starting from zero, will over time grow positively to unity at 90 degrees, decrease then to zero at 180 degrees, continuining to decrease to a negative one at 270 degrees, and finally return to zero as it completes a 360 degree rotation.

Now we can 'work backwards' to create an arbitrarily phase shifted waveform. From Figure 1, suppose we had a sine wave at zero degrees phase shift, and one at 90 degrees phase shift. From trigonometry, we know that the 'X' axis shadow is equal to the cosine of the angle (the magnitude is assumed to be unity as in the diagram. Likewise the 'Y' axis shadow is equal to the sine of the angle. Were we to multiply our cosine and sine signals by these values, and add them, the resultant would be the phase-shifted signal that will create these values.

Figure 2 shows a simple test circuit to examine a model that has for an output an unshifted sine wave output, and a phase shifted output: Figure 2
SIMPLE AC phase shift circuit

This simple circuit has one signal input represented by source V3, (Phased). It sets the desired phase shift in degrees respectively. There are two outputs. They are 'N1', the reference sine waveform and 'N2', the phase shifted sine waveform.

V1 is the aforementioned sine wave source. This signal is also used as an input to the B2 source, which is a voltage to current generator. Its equation is:

i = 2*(355/113)*{Freq}*V(4)

Here, 355/113 is a convenient approximation for the value of Pi. The sine wave is integrated by the capacitor, however it must be scaled as a function of frequency. B1 generator does the real work. Its equation is:

v = {Amplitude}*( cos(v(Phased)*355/(113*180))*v(4) + sin(v(Phased)*355/(113*180))*v(8))

Here the values of the decomposed vector sine and cosine generators are scaled and added to produce the overall phase shifted sine wave output.

Note that the capacitor C1 is set for an initial condition of -1V, and the analysis flag is set to use initial conditions.

A graph of the circuit output as shown shown in Figure 3 following: Figure 3
SIMPLE AC phase shift circuit graph

The RED trace is the unshifted sine wave at the N1 output. The green trace is the unshifted cosine waveform. The blue trace is the 135 degree shifted waveform.

After performing some other tests, the circuit seems to be working correctly, hence a parameterized subcircuit was made of the device and used together on a schematic as shown in Figure 4 following: Figure 4
Phase shift circuit with device model

The device works as expected. A netlist for the U1 device is:

************************
* B2 Spice Subcircuit
************************
* Created by Harvey C. Morehouse
* Phase shift input in degrees
* N1 is the unshifted output sine wave
* N2 is the shifted sine wave output
*
* The phase shift input may be a variable.
*
* This circuit may be freely copied by any individual user but is it requested that the
* original netlist be retained.
* Pin # Pin Name
* Phased Phased
* N2 N2
* N1 N1
.Subckt PSHIFT Phased N2 N1
***** main circuit
B1 N2 0 v = {Amplitude}*( cos(v(Phased)*355/(113*180))*v(4) + sin(v(Phased)*355/(113*180))*v(8))
V1 4 0 SIN( 0.000000000000e+000 1.000000000000e+000 {Freq} 0.000000000000e+000 0.000000000000e+000)
B2 0 8 i = 2*(355/113)*{Freq}*V(4)
C1 8 0 1 ic = {-1}
E1 N1 0 4 0 3.999999983616e+000
.ends

Creating a 3-phase Generator:

A three phase generator may be easily created by modifying the circuit of Figure 4 slightly. In this case, as the three voltage phases will not normally vary in phase one to another, the phase shift will not be used as a parameter. The circuit is shown in Figure 5 following: Figure 5
3 phase generator circuit

The circuit is straight-forward. Note that the generator has a common connection as would a WYE connection. This means that the individual phase loads could be from the U1 outputs to ground, or from phase-output to phase-output. If the output loads are connected from phase to phase a DELTA source supply is indicated, however the voltage input magnitude entered does not equal the phase to phase voltage magnitude.

It is simple enough to create a 6 phase version of the generator by including additional 'B' sources, but each shifted by 60 degree intervals instead of the 120 electrical degrees as shown in Figure 5. This will be left as an exercise for the reader.

A graph of the circuit of Figure 5 is shown in Figure 6 following: Figure 6
3 phase generator circuit graph

The red trace is phase one, which leades the green phase two race, which leads the blue phase three trace.

A netlist of the circuit is:

************************
* B2 Spice Subcircuit
************************
* Pin # Pin Name
* N2 N2
* N1 N1
* N3 N3
.Subckt 3PHGEN N2 N1 N3
*
* Created by Harvey Morehouse
*
* The individual phase voltages are representative of a WYE
* connection. That is, to a neutral ground connection.
*
* The circuit may be freely copied and used by individuals, however it is
* requested that the netlist retain the original information.
*
***** main circuit
B1 N2 0 v = {Amplitude}*( cos(120*355/(113*180))*v(4) + sin(120*355/(113*180))*v(8))
V1 4 0 SIN( 0.000000000000e+000 1.000000000000e+000 {Freq} 0.000000000000e+000 0.000000000000e+000)
B2 0 8 i = 2*(355/113)*{Freq}*V(4)
C1 8 0 1 ic = {-1}
E1 N1 0 4 0 9.999999959040e-001
B3 N3 0 v = {Amplitude}*( cos(240*355/(113*180))*v(4) + sin(240*355/(113*180))*v(8))
.ends

It is presumed that at some later time that the two devices created here will be included in the standard library, however until that time they may be created and used by individuals with a little effort.

Conclusions:

Two sinusoidal phase shift circuits have been prepared. The first creates a reference and a phase-shifted signal, that could be useful as a two-phase source or as a phase modulator circuit model. The second circuit is a three phase AC voltage source that could be useful in itself, and with a little effort turned in to a 6 phase AC source.